This site will look better if you upgrade to a browser that supports web standards.

Removing items from the Work Menu

Removing items manually

You can remove items from the Work menu by typing the CMD, OPT and - keys (that's the minus key from the main keyboard), then selecting the item from the menu. This works for any menu item in Word.

If the keyboard shortcut does nothing...

When Mac OS X's Universal Access (UA) is enabled, and zooming is turned on (perhaps via the CMD-OPT-8 key combo), the CMD-OPT-<minus> key combination is intercepted by the system to zoom the screen out. If your screen is already at max zoom, this will make the combination appear to do nothing.

If you want to leave UA enabled, type CMD-OPT-8, then CMD-OPT-<minus>. If you want to turn UA off, select the Keyboard Shortcuts tab from the System Preferences dialog. Uncheck the Universal Access checkbox.

Using a macro to delete selected items from the Work menu

This macro will allow you to selectively delete items from the Work menu. You can attach it to a toolbar button or a keyboard shorcut, or run it from the Tools/Macro/Macros dialog:

    Public Sub DeleteWorkMenuItems()
        Dim i As Long
        Dim nDelete As Long
        With WorkMenuItems
            For i = .Count To 1 Step -1
                nDelete = MsgBox( _
                    Prompt:="Delete """ & .Item(i).Name & """?", _
                    Buttons:=vbYesNoCancel, _
                    Title:="Delete Item from menu")
                If nDelete = vbCancel Then Exit For
                If nDelete = vbYes Then .Item(i).Delete
            Next i
        End With
    End Sub

Using a macro to delete ALL items from the Work menu

This macro will clear all items from the Work Menu:

    Public Sub ClearWorkMenu() 
        Dim wmItem As WorkMenuItem 
        For each wmItem in WorkMenuItems 
            wmItem.Delete 
        Next wmItem 
    End Sub

Adding a Delete item to the Work menu

You can put an item on the Work menu that will allow you to call the DeleteWorkMenuItems macro, above. Putting the following macros and DeleteWorkMenuItems in a regular code module in an add-in will place a new item on the Work menu to make deletions easier.

    Public Sub AutoExec()
        AddDeleteItemToWorkMenu
    End Sub

    Public Sub AutoClose()
        RemoveDeleteItemFromWorkMenu
    End Sub

    Private Sub AddDeleteItemToWorkMenu()
        Debug.Print "Add Delete Item"
        RemoveDeleteItemFromWorkMenu
        With CommandBars(1).FindControl(ID:=30100).Controls  'Work menu
            With .Add(Type:=msoControlButton, Before:=2, temporary:=True)
                .Caption = "Delete item from menu"
                .Tag = "jemWdWorkMenuDeleteItem"
                .Style = msoButtonCaption
                .OnAction = "DeleteWorkMenuItems"
            End With
        End With
    End Sub
    
    Private Sub RemoveDeleteItemFromWorkMenu()
        On Error Resume Next
        CommandBars.FindControl(Tag:="jemWdWorkMenuDeleteItem").Delete
        On Error GoTo 0
    End Sub

Click to download an add-in that puts this item on your Work menu, as well as saves your Work menu items in a text file.

This page last updated Tuesday, 1 March 2005

McGimpsey & Associates

Home

MacOffice